Edit C:\apache-tomcat-7.0.69\webapps\xmlui\themes\dri2xhtml\QDC-Handler.xsl

<?xml version="1.0" encoding="UTF-8"?>
<!--

The contents of this file are subject to the license and copyright
    detailed in the LICENSE and NOTICE files at the root of the source
    tree and available online at

http://www.dspace.org/license/

-->

<xsl:stylesheet 
    xmlns:i18n="http://apache.org/cocoon/i18n/2.1"
    xmlns:dri="http://di.tamu.edu/DRI/1.0/"
    xmlns:mets="http://www.loc.gov/METS/"
    xmlns:dc="http://purl.org/dc/elements/1.1/"
    xmlns:xlink="http://www.w3.org/TR/xlink/"
    xmlns:dcterms="http://purl.org/dc/terms/"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"
    xmlns="http://www.w3.org/1999/xhtml"
    exclude-result-prefixes="i18n dri mets dc xlink dcterms xsl">
    
    <xsl:output indent="yes"/>
    
    
    
       
    
    
    <xsl:template match="mets:METS[mets:dmdSec/mets:mdWrap[@OTHERMDTYPE='QDC' or @MDTYPE='DC']]" mode="summaryList">
        <xsl:choose>
            <xsl:when test="@LABEL='DSpace Item'">
                <xsl:call-template name="itemSummaryList-QDC"/>
            </xsl:when>
            <xsl:when test="@LABEL='DSpace Collection'">
                <xsl:call-template name="collectionSummaryList-QDC"/>
            </xsl:when>
            <xsl:when test="@LABEL='DSpace Community'">
                <xsl:call-template name="communitySummaryList-QDC"/>
            </xsl:when>                
            <xsl:otherwise>
                <i18n:text>xmlui.dri2xhtml.METS-1.0.non-conformant</i18n:text>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>
    
    
    
    
    
    <xsl:template name="itemSummaryList-QDC">
        
        <xsl:apply-templates select="./mets:dmdSec/mets:mdWrap[@OTHERMDTYPE='QDC' or @MDTYPE='DC']/mets:xmlData/*"
            mode="itemSummaryList-QDC"/>
        
        <xsl:apply-templates select="./mets:fileSec/mets:fileGrp[@USE='THUMBNAIL']"/>
    </xsl:template>
    
    
    
    <xsl:template match="dcterms:qualifieddc | dc:simpledc " mode="itemSummaryList-QDC"> 
        <div class="artifact-description">
            <div class="artifact-title">
                
                <a href="{ancestor::mets:METS/@OBJID}">
                    <xsl:choose>
                        <xsl:when test="dc:title">
                            <xsl:copy-of select="dc:title[1]/node()"/>
                        </xsl:when>
                        <xsl:otherwise>
                            <i18n:text>xmlui.dri2xhtml.METS-1.0.no-title</i18n:text>
                        </xsl:otherwise>
                    </xsl:choose>
                </a>
            </div>
            <div class="artifact-info">
                
                <span class="author">
                    <xsl:choose>
                        <xsl:when test="dc:contributor">
                            <xsl:copy-of select="dc:contributor[1]/child::node()"/>
                        </xsl:when>
                        <xsl:otherwise>
                            <i18n:text>xmlui.dri2xhtml.METS-1.0.no-author</i18n:text>
                        </xsl:otherwise>
                    </xsl:choose>
                </span>
                
                <xsl:choose>
                    <xsl:when test="name(.)= 'qualifieddc' ">             
                        <span class="date">(<xsl:copy-of select="substring(dcterms:issued/child::node(),1,10)"/>)</span>
                    </xsl:when>
                    <xsl:otherwise>
                        <span class="date">(<xsl:copy-of select="substring(dc:date[1]/child::node(),1,10)"/>)</span>
                    </xsl:otherwise>
                </xsl:choose>
            </div>
        </div>
    </xsl:template>
        
    <xsl:template name="collectionSummaryList-QDC">
        <i18n:text>xmlui.dri2xhtml.METS-1.0.qdc-not-applicable</i18n:text>
    </xsl:template>
    
    <xsl:template name="communitySummaryList-QDC">
        <i18n:text>xmlui.dri2xhtml.METS-1.0.qdc-not-applicable</i18n:text>
    </xsl:template>
    
    
    
    
    
    
    
    
    <xsl:template match="mets:METS[mets:dmdSec/mets:mdWrap[@OTHERMDTYPE='QDC' or @MDTYPE='DC']]" mode="detailList">
        <xsl:choose>
            <xsl:when test="@LABEL='DSpace Item'">
                <xsl:call-template name="itemDetailList-QDC"/>
            </xsl:when>
            <xsl:when test="@LABEL='DSpace Collection'">
                <xsl:call-template name="collectionDetailList-QDC"/>
            </xsl:when>
            <xsl:when test="@LABEL='DSpace Community'">
                <xsl:call-template name="communityDetailList-QDC"/>
            </xsl:when>                
            <xsl:otherwise>
                <i18n:text>xmlui.dri2xhtml.METS-1.0.non-conformant</i18n:text>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>
    
    
    <xsl:template name="itemDetailList-QDC">
        
        <xsl:apply-templates select="./mets:dmdSec/mets:mdWrap[@OTHERMDTYPE='QDC' or @MDTYPE='DC']/mets:xmlData/*"
            mode="itemSummaryList-QDC"/>
        
        <xsl:apply-templates select="./mets:fileSec/mets:fileGrp[@USE='THUMBNAIL']"/>
    </xsl:template>
    
    
    <xsl:template name="collectionDetailList-QDC">
        <i18n:text>xmlui.dri2xhtml.METS-1.0.qdc-not-applicable</i18n:text>
    </xsl:template>
    
    <xsl:template name="communityDetailList-QDC">
        <i18n:text>xmlui.dri2xhtml.METS-1.0.qdc-not-applicable</i18n:text>
    </xsl:template>
    
    
    
    
    
    
    
    
    
    <xsl:template match="mets:METS[mets:dmdSec/mets:mdWrap[@OTHERMDTYPE='QDC' or @MDTYPE='DC']]" mode="summaryView">
        <xsl:choose>
            <xsl:when test="@LABEL='DSpace Item'">
                <xsl:call-template name="itemSummaryView-QDC"/>
            </xsl:when>
            <xsl:when test="@LABEL='DSpace Collection'">
                <xsl:call-template name="collectionSummaryView-QDC"/>
            </xsl:when>
            <xsl:when test="@LABEL='DSpace Community'">
                <xsl:call-template name="communitySummaryView-QDC"/>
            </xsl:when>                
            <xsl:otherwise>
                <i18n:text>xmlui.dri2xhtml.METS-1.0.non-conformant</i18n:text>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>
    
    
    <xsl:template name="itemSummaryView-QDC">
        
        <xsl:apply-templates select="./mets:dmdSec/mets:mdWrap[@OTHERMDTYPE='QDC' or @MDTYPE='DC']/mets:xmlData/*"
            mode="itemSummaryView-QDC"/>
        
        
        <xsl:apply-templates select="./mets:fileSec/mets:fileGrp[@USE='CONTENT']">
            <xsl:with-param name="context" select="."/>
            <xsl:with-param name="primaryBitstream" select="./mets:structMap[@TYPE='LOGICAL']/mets:div[@TYPE='DSpace Item']/mets:fptr/@FILEID"/>
        </xsl:apply-templates>
        
        
        <xsl:apply-templates select="./mets:fileSec/mets:fileGrp[@USE='CC-LICENSE' or @USE='LICENSE']"/>
        
    </xsl:template>
    
    
    
    
    <xsl:template match="dcterms:qualifieddc | dc:simpledc" mode="itemSummaryView-QDC">
        <table class="ds-includeSet-table">
            
            <tr class="ds-table-row even">
                <td><span class="bold"><i18n:text>xmlui.dri2xhtml.METS-1.0.item-title</i18n:text>:</span></td>
                <td>
                    <xsl:choose>
                        <xsl:when test="dc:title">
                            <xsl:copy-of select="dc:title[1]/child::node()"/>
                        </xsl:when>
                        <xsl:otherwise>
                            <i18n:text>xmlui.dri2xhtml.METS-1.0.no-title</i18n:text>
                        </xsl:otherwise>
                    </xsl:choose>
                </td>
            </tr>
            <tr class="ds-table-row odd">
                <td><span class="bold"><i18n:text>xmlui.dri2xhtml.METS-1.0.item-author</i18n:text>:</span></td>
                <td><xsl:copy-of select="dc:contributor[1]/child::node()"/></td>
            </tr>
            <tr class="ds-table-row even">
                <td><span class="bold"><i18n:text>xmlui.dri2xhtml.METS-1.0.item-abstract</i18n:text>:</span></td>
                <td><xsl:copy-of select="dcterms:abstract/child::node()"/></td>
            </tr>
            <tr class="ds-table-row odd">
                <td><span class="bold"><i18n:text>xmlui.dri2xhtml.METS-1.0.item-description</i18n:text>:</span></td>
                <td><xsl:copy-of select="dc:description/child::node()"/></td>
            </tr>
            <tr class="ds-table-row even">
                <td><span class="bold"><i18n:text>xmlui.dri2xhtml.METS-1.0.item-uri</i18n:text>:</span></td>
                <td>
                    <a>
                        <xsl:attribute name="href">
                            <xsl:copy-of select="dc:identifier[@type='dcterms:URI'][1]/child::node()"/>
                        </xsl:attribute>
                        <xsl:copy-of select="dc:identifier[@type='dcterms:URI'][1]/child::node()"/>
                    </a>
                </td>
            </tr>
            <tr class="ds-table-row odd">
                <td><span class="bold"><i18n:text>xmlui.dri2xhtml.METS-1.0.item-date</i18n:text>:</span></td>
                <td><xsl:copy-of select="substring(dcterms:issued/child::node(),1,10)"/></td>
            </tr>
        </table>
        
    </xsl:template>
    
    
    
    
    <xsl:template name="collectionSummaryView-QDC">
        <i18n:text>xmlui.dri2xhtml.METS-1.0.qdc-not-applicable</i18n:text>
    </xsl:template>
    
    <xsl:template name="communitySummaryView-QDC">
        <i18n:text>xmlui.dri2xhtml.METS-1.0.qdc-not-applicable</i18n:text>
    </xsl:template>
    
    
    
    
    
    
    
    
    <xsl:template match="mets:METS[mets:dmdSec/mets:mdWrap[@OTHERMDTYPE='QDC' or @MDTYPE='DC']]" mode="detailView">
        <xsl:choose>
            <xsl:when test="@LABEL='DSpace Item'">
                <xsl:call-template name="itemDetailView-QDC"/>
            </xsl:when>
            <xsl:when test="@LABEL='DSpace Collection'">
                <xsl:call-template name="collectionDetailView-QDC"/>
            </xsl:when>
            <xsl:when test="@LABEL='DSpace Community'">
                <xsl:call-template name="communityDetailView-QDC"/>
            </xsl:when>                
            <xsl:otherwise>
                <i18n:text>xmlui.dri2xhtml.METS-1.0.non-conformant</i18n:text>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>
    
    
    
    
    <xsl:template name="itemDetailView-QDC">
        
        
        <xsl:apply-templates select="mets:dmdSec/mets:mdWrap[@OTHERMDTYPE='QDC' or @MDTYPE='DC']/mets:xmlData/*"
            mode="itemDetailView-QDC"/>
        
        
        <xsl:apply-templates select="mets:fileSec/mets:fileGrp[@USE='CONTENT']">
            <xsl:with-param name="context" select="."/>
            <xsl:with-param name="primaryBitstream" select="./mets:structMap[@TYPE='LOGICAL']/mets:div[@TYPE='DSpace Item']/mets:fptr/@FILEID"/>
        </xsl:apply-templates>
        
        
        <xsl:apply-templates select="mets:fileSec/mets:fileGrp[@USE='CC-LICENSE' or @USE='LICENSE']"/>
        
    </xsl:template>
    
        
    
    <xsl:template match="dcterms:qualifieddc | dc:simpledc " mode="itemDetailView-QDC" priority="2">
        <h3 class="ds-includeSet-table-header"><i18n:text>xmlui.dri2xhtml.METS-1.0.header-qdc-elements</i18n:text></h3>
		<table class="ds-includeSet-table">
		    <xsl:for-each select="*[namespace-uri(.)='http://purl.org/dc/elements/1.1/']">
                <tr>
                    <xsl:attribute name="class">
                        <xsl:text>ds-table-row </xsl:text>
                        <xsl:if test="(position() mod 2 = 0)">even </xsl:if>
                        <xsl:if test="(position() mod 2 = 1)">odd </xsl:if>
                    </xsl:attribute>
                    <td>
                        <xsl:text>dc.</xsl:text>
                        <xsl:value-of select="local-name(.)"/>
                        <xsl:if test="./@type">
                            <xsl:text>.</xsl:text>
                            <xsl:value-of select="./@type"/>
                        </xsl:if>
                    </td>
                    <td><xsl:copy-of select="./child::node()"/></td>
                    <td><xsl:value-of select="./@xml:lang"/></td>
                </tr>
            </xsl:for-each>
		</table>
        <h3 class="ds-includeSet-table-header"><i18n:text>xmlui.dri2xhtml.METS-1.0.header-qdc-terms</i18n:text></h3>
		<table class="ds-includeSet-table">
		    <xsl:for-each select="*[namespace-uri(.)='http://purl.org/dc/terms/']">
                <tr>
                    <xsl:attribute name="class">
                        <xsl:text>ds-table-row </xsl:text>
                        <xsl:if test="(position() mod 2 = 0)">even </xsl:if>
                        <xsl:if test="(position() mod 2 = 1)">odd </xsl:if>
                    </xsl:attribute>
                    <td>
                        <xsl:text>dcterms.</xsl:text>
                        <xsl:value-of select="local-name(.)"/>
                        <xsl:if test="./@type">
                            <xsl:text>.</xsl:text>
                            <xsl:value-of select="./@type"/>
                        </xsl:if>
                    </td>
                    <td><xsl:copy-of select="./child::node()"/></td>
                    <td><xsl:value-of select="./@xml:lang"/></td>
                </tr>
            </xsl:for-each>
		</table>
	</xsl:template>	
	
	    
    
    <xsl:template name="collectionDetailView-QDC">
        <i18n:text>xmlui.dri2xhtml.METS-1.0.qdc-not-applicable</i18n:text>
    </xsl:template>
    
    <xsl:template name="communityDetailView-QDC">
        <i18n:text>xmlui.dri2xhtml.METS-1.0.qdc-not-applicable</i18n:text>
    </xsl:template>
      
    
</xsl:stylesheet>

Ms-Dos/Windows Unix Write backup

jsp File Browser version 1.2 by www.vonloesch.de